Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00085_TargetListMgmt.ls

Text File | 2004-07-11 | 5.1 KB | 212 lines

--
-- TargetListMgmt
--

property ancestor

property targetList  -- a specially formatted list of target sprites

property targetSpriteColor   -- the scoreColor of target sprites (to receive draggables)
property targetDataMember


on new me
  -- constants:
  set targetDataMember = "TargetPredefines"
  set targetSpriteColor = 3  -- corresponds to blue in the score.

  set ancestor = new (script "DragMemberMgmt")

  gatherTargetSpriteInfo (me)
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


on gathertargetSpriteInfo me
  -- get presaved target data if we are in protected mode:
  if the movieName contains ".dxr" or the movieName contains ".exe" then
    set targetList = value (field targetDataMember)
    return
  end if

  set initList = [:]
  set num = 0

  --cycle through all sprites:
  repeat with spr = 1 to numSprites (me)

    -- target sprites must be certain colors to be used in the DragDrop Game:
    if the scoreColor of sprite spr = targetSpriteColor then
      set num = num + 1
      -- gather usable information:
      -- as there will be no randomization with the targets (order may be important)
      -- we can initialize the information here:
      set tmpLst = [#loc:(the loc of sprite spr), #identifier:value ("#" & the name of member the memberNum of sprite spr of castLib the castLibNum of sprite spr), #myNum:the memberNum of sprite spr, #myLib:the castLibNum of sprite spr,  #showFlag:0]

      -- add to the initList
      addProp (initList, spr, tmpLst)
    else

    end if
  end repeat

  if not count (initList) then alert "There are no target sprites for this activity.  Check sprite score colors."
  else
    set targetList = initList
    makeField (me, targetDataMember, targetList)
  end if
end


-- return TRUE if the sprite is a target:

on istarget me, spr
  if voidP (getAProp (targetList, spr)) then return 0
  else return 1
end



-- return a prop list of all target names and sprites
-- as follows: [#identifier:[spr,spr,spr],#identifier:[spr,spr]]

on gettargetSpritePool me
  set lst = [:]
  -- get all #identifiers used by given target sprites:
  set num = count (targetList)

  repeat with i = 1 to num
    set spr = getPropAt (targetList, i)
    set rec = getAProp (targetList,spr)
    set id = getAProp (rec, #identifier)

    -- add a sprite to the list of that target identifier's sprites
    if not voidP (id) then
      set tmp = getAProp (lst, id)
      if not listP (tmp) then set tmp = []
      add (tmp, spr)
      setAProp (lst, id, tmp)
    end if
  end repeat
  return lst
end


-- return a straight list of target sprites:

on gettargetSprites me
  set lst = []
  set c = count (targetList)
  repeat with i = 1 to c
    add (lst, getPropAt (targetList, i))
  end repeat
  return lst
end



-- set up a temporary data structure that lists all of the members divided into lists.. Return this form:
-- [#identifier:[memberName:memberNum, memberName:memberNum], ... ]

on setUptargetPool me
  set pool = [:]

  -- there is only one list of draggable members at this point
  -- in the form: [castLibNum:[memberName:memberNum, ... ]]
  set memberList = the memberList of ancestor
  set cst = getPropAt (memberList, 1)
  set memLst = getaProp (memberList, cst)

  if voidP (memLst) then
    alert "The memberList is not formatted properly."
    return 0
  end if

  set num = count (targetList)
  repeat with i = 1 to num
    set spr = getPropAt (targetList, i)
    set lst = getAProp (targetList, spr)
    set name = getaProp (lst, #identifier)

    if not voidP (name) then
      set tmp = [:]
      addProp (tmp, name, 0)
      addProp (pool, name, returnPropMatchList (me, memLst, tmp))
    end if
  end repeat

  if the optionDown then put "targetPool:" && pool
  return pool
end


on hideTargets me
  set num = count (targetList)
  repeat with i = 1 to num
    set spr = getPropAt (targetList, i)
    hideTarget (me, spr)
  end repeat
end


on showTargets me
  set num = count (targetList)
  repeat with i = 1 to num
    set spr = getPropAt (targetList, i)
    showTarget (me, spr)
  end repeat
end


-- mark the target as having been dragged to.
-- return true if the target has been successfully marked.
-- show the target hot spot.

on showTarget me, spr
  set lst = getAProp (targetList, spr)
  if voidP (lst) then return 0

  setAProp (lst, #showFlag, 1)
  setAProp (targetList, spr, lst)
  return 1
end


-- mark the target as having been dragged to.
-- return true if the target has been successfully marked.
-- hide the target hot spot.

on hideTarget me, spr
  set lst = getAProp (targetList, spr)
  if voidP (lst) then return 0

  setAProp (lst, #showFlag, 0)
  setAProp (targetList, spr, lst)
  return 1
end


-- check if we are done by seeing any of the targets still have hotspots.
-- if they are all disabled, then we are finished.

on checkDoneTargets me
  set num = count (targetList)

  repeat with i = 1 to num
    set spr = getPropAt (targetList, i)
    set lst = getProp (targetList, spr)

    if getAProp (lst, #showFlag) then return 0
  end repeat

  return 1
end